mirror of
git://git.sv.gnu.org/emacs.git
synced 2026-01-13 15:00:42 -08:00
ecf08f0621
dc4e6b1329; Update copyright years in more files64b3777631; Run set-copyright from admin.el8e1c56ae46; Add 2024 to copyright years # Conflicts: # doc/misc/modus-themes.org # doc/misc/texinfo.tex # etc/NEWS # etc/refcards/ru-refcard.tex # etc/themes/modus-operandi-theme.el # etc/themes/modus-themes.el # etc/themes/modus-vivendi-theme.el # lib/alloca.in.h # lib/binary-io.h # lib/c-ctype.h # lib/c-strcasecmp.c # lib/c-strncasecmp.c # lib/careadlinkat.c # lib/cloexec.c # lib/close-stream.c # lib/diffseq.h # lib/dup2.c # lib/filemode.h # lib/fpending.c # lib/fpending.h # lib/fsusage.c # lib/getgroups.c # lib/getloadavg.c # lib/gettext.h # lib/gettime.c # lib/gettimeofday.c # lib/group-member.c # lib/malloc.c # lib/md5-stream.c # lib/md5.c # lib/md5.h # lib/memmem.c # lib/memrchr.c # lib/nanosleep.c # lib/save-cwd.h # lib/sha1.c # lib/sig2str.c # lib/stdlib.in.h # lib/strtoimax.c # lib/strtol.c # lib/strtoll.c # lib/time_r.c # lib/xalloc-oversized.h # lisp/auth-source-pass.el # lisp/emacs-lisp/lisp-mnt.el # lisp/emacs-lisp/timer.el # lisp/info-look.el # lisp/jit-lock.el # lisp/loadhist.el # lisp/mail/rmail.el # lisp/net/ntlm.el # lisp/net/webjump.el # lisp/progmodes/asm-mode.el # lisp/progmodes/project.el # lisp/progmodes/sh-script.el # lisp/textmodes/flyspell.el # lisp/textmodes/reftex-toc.el # lisp/textmodes/reftex.el # lisp/textmodes/tex-mode.el # lisp/url/url-gw.el # m4/alloca.m4 # m4/clock_time.m4 # m4/d-type.m4 # m4/dirent_h.m4 # m4/dup2.m4 # m4/euidaccess.m4 # m4/fchmodat.m4 # m4/filemode.m4 # m4/fsusage.m4 # m4/getgroups.m4 # m4/getloadavg.m4 # m4/getrandom.m4 # m4/gettime.m4 # m4/gettimeofday.m4 # m4/gnulib-common.m4 # m4/group-member.m4 # m4/inttypes.m4 # m4/malloc.m4 # m4/manywarnings.m4 # m4/mempcpy.m4 # m4/memrchr.m4 # m4/mkostemp.m4 # m4/mktime.m4 # m4/nproc.m4 # m4/nstrftime.m4 # m4/pathmax.m4 # m4/pipe2.m4 # m4/pselect.m4 # m4/pthread_sigmask.m4 # m4/readlink.m4 # m4/realloc.m4 # m4/sig2str.m4 # m4/ssize_t.m4 # m4/stat-time.m4 # m4/stddef_h.m4 # m4/stdint.m4 # m4/stdio_h.m4 # m4/stdlib_h.m4 # m4/stpcpy.m4 # m4/strnlen.m4 # m4/strtoimax.m4 # m4/strtoll.m4 # m4/time_h.m4 # m4/timegm.m4 # m4/timer_time.m4 # m4/timespec.m4 # m4/unistd_h.m4 # m4/warnings.m4 # nt/configure.bat # nt/preprep.c # test/lisp/register-tests.el
82 lines
2.9 KiB
Text
82 lines
2.9 KiB
Text
# serial 34
|
|
|
|
# Copyright (C) 1997-2001, 2003-2024 Free Software Foundation, Inc.
|
|
#
|
|
# This file is free software; the Free Software Foundation
|
|
# gives unlimited permission to copy and/or distribute it,
|
|
# with or without modifications, as long as this notice is preserved.
|
|
|
|
dnl From Jim Meyering.
|
|
|
|
AC_DEFUN([gl_FUNC_LSTAT],
|
|
[
|
|
AC_REQUIRE([AC_CANONICAL_HOST])
|
|
AC_REQUIRE([gl_SYS_STAT_H_DEFAULTS])
|
|
dnl If lstat does not exist, the replacement <sys/stat.h> does
|
|
dnl "#define lstat stat", and lstat.c is a no-op.
|
|
AC_CHECK_FUNCS_ONCE([lstat])
|
|
if test $ac_cv_func_lstat = yes; then
|
|
AC_REQUIRE([gl_FUNC_LSTAT_FOLLOWS_SLASHED_SYMLINK])
|
|
case $host_os,$gl_cv_func_lstat_dereferences_slashed_symlink in
|
|
solaris* | *no)
|
|
REPLACE_LSTAT=1
|
|
;;
|
|
esac
|
|
else
|
|
HAVE_LSTAT=0
|
|
fi
|
|
])
|
|
|
|
# Prerequisites of lib/lstat.c.
|
|
AC_DEFUN([gl_PREREQ_LSTAT], [:])
|
|
|
|
AC_DEFUN([gl_FUNC_LSTAT_FOLLOWS_SLASHED_SYMLINK],
|
|
[
|
|
dnl We don't use AC_FUNC_LSTAT_FOLLOWS_SLASHED_SYMLINK any more, because it
|
|
dnl is no longer maintained in Autoconf and because it invokes AC_LIBOBJ.
|
|
AC_REQUIRE([AC_CANONICAL_HOST]) dnl for cross-compiles
|
|
AC_CACHE_CHECK([whether lstat correctly handles trailing slash],
|
|
[gl_cv_func_lstat_dereferences_slashed_symlink],
|
|
[rm -f conftest.sym conftest.file
|
|
echo >conftest.file
|
|
AC_RUN_IFELSE(
|
|
[AC_LANG_PROGRAM(
|
|
[AC_INCLUDES_DEFAULT],
|
|
[[struct stat sbuf;
|
|
if (symlink ("conftest.file", "conftest.sym") != 0)
|
|
return 1;
|
|
/* Linux will dereference the symlink and fail, as required by
|
|
POSIX. That is better in the sense that it means we will not
|
|
have to compile and use the lstat wrapper. */
|
|
return lstat ("conftest.sym/", &sbuf) == 0;
|
|
]])],
|
|
[gl_cv_func_lstat_dereferences_slashed_symlink=yes],
|
|
[gl_cv_func_lstat_dereferences_slashed_symlink=no],
|
|
[case "$host_os" in
|
|
linux-* | linux)
|
|
# Guess yes on Linux systems.
|
|
gl_cv_func_lstat_dereferences_slashed_symlink="guessing yes" ;;
|
|
midipix*)
|
|
# Guess yes on systems that emulate the Linux system calls.
|
|
gl_cv_func_lstat_dereferences_slashed_symlink="guessing yes" ;;
|
|
*-gnu* | gnu*)
|
|
# Guess yes on glibc systems.
|
|
gl_cv_func_lstat_dereferences_slashed_symlink="guessing yes" ;;
|
|
mingw*)
|
|
# Guess no on native Windows.
|
|
gl_cv_func_lstat_dereferences_slashed_symlink="guessing no" ;;
|
|
*)
|
|
# If we don't know, obey --enable-cross-guesses.
|
|
gl_cv_func_lstat_dereferences_slashed_symlink="$gl_cross_guess_normal" ;;
|
|
esac
|
|
])
|
|
rm -f conftest.sym conftest.file
|
|
])
|
|
case "$gl_cv_func_lstat_dereferences_slashed_symlink" in
|
|
*yes)
|
|
AC_DEFINE_UNQUOTED([LSTAT_FOLLOWS_SLASHED_SYMLINK], [1],
|
|
[Define to 1 if 'lstat' dereferences a symlink specified
|
|
with a trailing slash.])
|
|
;;
|
|
esac
|
|
])
|