mirror of
git://git.sv.gnu.org/emacs.git
synced 2025-12-30 00:51:50 -08:00
78669517dc
This incorporates: 2019-09-22 Update some URLs 2019-09-15 fcntl-h: fix compilation error of creat.c on MSVC 2019-09-15 creat: new module 2019-09-15 access: new module 2019-09-09 Add option to assume best, not worst, when cross-compiling. * build-aux/config.guess, build-aux/config.sub, doc/misc/texinfo.tex: * lib/careadlinkat.c, lib/careadlinkat.h, lib/count-leading-zeros.h: * lib/count-trailing-zeros.h, lib/diffseq.h, lib/fcntl.in.h: * lib/ftoastr.c, lib/get-permissions.c: * lib/ieee754.in.h, lib/inttypes.in.h, lib/mktime.c, lib/open.c: * lib/pathmax.h, lib/pipe2.c, lib/stddef.in.h, lib/stdint.in.h: * lib/stdlib.in.h, lib/str-two-way.h, lib/string.in.h, lib/time.in.h: * lib/timegm.c, lib/unistd.in.h, m4/canonicalize.m4: * m4/extern-inline.m4, m4/fcntl_h.m4, m4/fdopendir.m4: * m4/getgroups.m4, m4/getopt.m4, m4/gettimeofday.m4: * m4/gnulib-common.m4, m4/largefile.m4: * m4/lstat.m4, m4/memmem.m4, m4/mktime.m4, m4/nocrash.m4, m4/open.m4: * m4/pselect.m4, m4/putenv.m4, m4/readlink.m4, m4/regex.m4: * m4/symlink.m4, m4/unistd_h.m4, m4/utimens.m4, m4/utimes.m4: Copy from Gnulib. * lib/gnulib.mk.in, m4/gnulib-comp.m4: Regenerate. * m4/open-slash.m4: New file, copied from Gnulib.
60 lines
1.9 KiB
Text
60 lines
1.9 KiB
Text
# putenv.m4 serial 24
|
|
dnl Copyright (C) 2002-2019 Free Software Foundation, Inc.
|
|
dnl This file is free software; the Free Software Foundation
|
|
dnl gives unlimited permission to copy and/or distribute it,
|
|
dnl with or without modifications, as long as this notice is preserved.
|
|
|
|
dnl From Jim Meyering.
|
|
dnl
|
|
dnl Check whether putenv ("FOO") removes FOO from the environment.
|
|
dnl The putenv in libc on at least SunOS 4.1.4 does *not* do that.
|
|
|
|
AC_DEFUN([gl_FUNC_PUTENV],
|
|
[
|
|
AC_REQUIRE([gl_STDLIB_H_DEFAULTS])
|
|
AC_REQUIRE([AC_CANONICAL_HOST]) dnl for cross-compiles
|
|
AC_CACHE_CHECK([for putenv compatible with GNU and SVID],
|
|
[gl_cv_func_svid_putenv],
|
|
[AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],[[
|
|
/* Put it in env. */
|
|
if (putenv ("CONFTEST_putenv=val"))
|
|
return 1;
|
|
|
|
/* Try to remove it. */
|
|
if (putenv ("CONFTEST_putenv"))
|
|
return 2;
|
|
|
|
/* Make sure it was deleted. */
|
|
if (getenv ("CONFTEST_putenv") != 0)
|
|
return 3;
|
|
|
|
return 0;
|
|
]])],
|
|
gl_cv_func_svid_putenv=yes,
|
|
gl_cv_func_svid_putenv=no,
|
|
dnl When crosscompiling, assume putenv is broken.
|
|
[case "$host_os" in
|
|
# Guess yes on glibc systems.
|
|
*-gnu* | gnu*) gl_cv_func_svid_putenv="guessing yes" ;;
|
|
# Guess yes on musl systems.
|
|
*-musl*) gl_cv_func_svid_putenv="guessing yes" ;;
|
|
# Guess no on native Windows.
|
|
mingw*) gl_cv_func_svid_putenv="guessing no" ;;
|
|
# If we don't know, obey --enable-cross-guesses.
|
|
*) gl_cv_func_svid_putenv="$gl_cross_guess_normal" ;;
|
|
esac
|
|
])
|
|
])
|
|
case "$gl_cv_func_svid_putenv" in
|
|
*yes) ;;
|
|
*)
|
|
REPLACE_PUTENV=1
|
|
;;
|
|
esac
|
|
])
|
|
|
|
# Prerequisites of lib/putenv.c.
|
|
AC_DEFUN([gl_PREREQ_PUTENV],
|
|
[
|
|
AC_CHECK_DECLS([_putenv])
|
|
])
|