mirror of
git://git.sv.gnu.org/emacs.git
synced 2026-03-04 13:03:09 -08:00
846657afaf
This incorporates: 2020-08-16 time_rz: remove unused functions 2020-08-16 time_rz: fix issues with mktime_z failures 2020-08-16 nstrftime: Guide inlining also on clang 2020-08-16 intprops: Avoid bogus warning on clang 2020-08-16 libc-config: Enable __REDIRECT macro also on clang 2020-08-16 regex: Use initializer shorthand syntax also with clang 2020-08-16 regex: Use space optimization also with clang 2020-08-16 Use _Static_assert and static_assert when present on clang 2020-08-16 Use 'throw ()' for optimization in C++ mode also on clang 2020-08-16 stdio: Don't break attribute 'scanf' on clang 2020-08-16 Fix "warning: 'format' attribute ...: rpl_printf" 2020-08-16 Fix "warning: attribute declaration must precede definition" 2020-08-16 Fix undesired warnings 2020-08-16 Don't use Autoconf quadrigraphsxo 2020-08-16 Fix quoting of AC_LANG_PROGRAM arguments 2020-08-16 Assume autoconf >= 2.64 2020-08-15 nstrftime: be more predictable about errno 2020-08-15 canonicalize: Fix autoconf test on MSVC/clang 2020-08-15 Support compiling without -loldnames on native Windows 2020-08-14 mktime, mktime-internal: Remove obsolete code 2020-08-14 Assume tzset exists * lib/c++defs.h, lib/canonicalize-lgpl.c, lib/cdefs.h, lib/dup2.c: * lib/fcntl.in.h, lib/getopt-cdefs.in.h, lib/intprops.h, lib/md5.h: * lib/mktime.c, lib/nstrftime.c, lib/open.c, lib/regcomp.c: * lib/regex_internal.h, lib/stdio.in.h, lib/stdlib.in.h: * lib/strftime.h, lib/string.in.h, lib/sys_select.in.h: * lib/sys_stat.in.h, lib/sys_time.in.h, lib/time.in.h, lib/time_rz.c: * lib/unistd.in.h, lib/verify.h, m4/00gnulib.m4: * m4/absolute-header.m4, m4/alloca.m4, m4/canonicalize.m4, m4/dup2.m4: * m4/fchmodat.m4, m4/fcntl.m4, m4/fdopendir.m4, m4/fpending.m4: * m4/futimens.m4, m4/getdtablesize.m4, m4/getloadavg.m4: * m4/gnulib-common.m4, m4/include_next.m4, m4/largefile.m4: * m4/manywarnings.m4, m4/mktime.m4, m4/nstrftime.m4, m4/open-slash.m4: * m4/pselect.m4, m4/pthread_sigmask.m4, m4/time_h.m4, m4/utimens.m4: * m4/utimensat.m4, m4/utimes.m4, m4/warnings.m4: Copy from Gnulib. * lib/gnulib.mk.in: Regenerate.
85 lines
3.5 KiB
Text
85 lines
3.5 KiB
Text
# 00gnulib.m4 serial 8
|
|
dnl Copyright (C) 2009-2020 Free Software Foundation, Inc.
|
|
dnl This file is free software; the Free Software Foundation
|
|
dnl gives unlimited permission to copy and/or distribute it,
|
|
dnl with or without modifications, as long as this notice is preserved.
|
|
|
|
dnl This file must be named something that sorts before all other
|
|
dnl gnulib-provided .m4 files. It is needed until the clang fix has
|
|
dnl been included in Autoconf.
|
|
|
|
# The following definitions arrange to use a compiler option
|
|
# -Werror=implicit-function-declaration in AC_CHECK_DECL, when the
|
|
# compiler is clang. Without it, clang implicitly declares "known"
|
|
# library functions in C mode, but not in C++ mode, which would cause
|
|
# Gnulib to omit a declaration and thus later produce an error in C++
|
|
# mode. As of clang 9.0, these "known" functions are identified through
|
|
# LIBBUILTIN invocations in the LLVM source file
|
|
# llvm/tools/clang/include/clang/Basic/Builtins.def.
|
|
# It's not possible to AC_REQUIRE the extra tests from AC_CHECK_DECL,
|
|
# because AC_CHECK_DECL, like other Autoconf built-ins, is not supposed
|
|
# to AC_REQUIRE anything: some configure.ac files have their first
|
|
# AC_CHECK_DECL executed conditionally. Therefore append the extra tests
|
|
# to AC_PROG_CC.
|
|
AC_DEFUN([gl_COMPILER_CLANG],
|
|
[
|
|
dnl AC_REQUIRE([AC_PROG_CC])
|
|
AC_CACHE_CHECK([whether the compiler is clang],
|
|
[gl_cv_compiler_clang],
|
|
[dnl Use _AC_COMPILE_IFELSE instead of AC_EGREP_CPP, to avoid error
|
|
dnl "circular dependency of AC_LANG_COMPILER(C)" if AC_PROG_CC has
|
|
dnl not yet been invoked.
|
|
_AC_COMPILE_IFELSE(
|
|
[AC_LANG_PROGRAM([[
|
|
#ifdef __clang__
|
|
barfbarf
|
|
#endif
|
|
]],[[]])
|
|
],
|
|
[gl_cv_compiler_clang=no],
|
|
[gl_cv_compiler_clang=yes])
|
|
])
|
|
])
|
|
AC_DEFUN([gl_COMPILER_PREPARE_CHECK_DECL],
|
|
[
|
|
dnl AC_REQUIRE([AC_PROG_CC])
|
|
dnl AC_REQUIRE([gl_COMPILER_CLANG])
|
|
AC_CACHE_CHECK([for compiler option needed when checking for declarations],
|
|
[gl_cv_compiler_check_decl_option],
|
|
[if test $gl_cv_compiler_clang = yes; then
|
|
dnl Test whether the compiler supports the option
|
|
dnl '-Werror=implicit-function-declaration'.
|
|
save_ac_compile="$ac_compile"
|
|
ac_compile="$ac_compile -Werror=implicit-function-declaration"
|
|
dnl Use _AC_COMPILE_IFELSE instead of AC_COMPILE_IFELSE, to avoid a
|
|
dnl warning "AC_COMPILE_IFELSE was called before AC_USE_SYSTEM_EXTENSIONS".
|
|
_AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]],[[]])],
|
|
[gl_cv_compiler_check_decl_option='-Werror=implicit-function-declaration'],
|
|
[gl_cv_compiler_check_decl_option=none])
|
|
ac_compile="$save_ac_compile"
|
|
else
|
|
gl_cv_compiler_check_decl_option=none
|
|
fi
|
|
])
|
|
if test "x$gl_cv_compiler_check_decl_option" != xnone; then
|
|
ac_compile_for_check_decl="$ac_compile $gl_cv_compiler_check_decl_option"
|
|
else
|
|
ac_compile_for_check_decl="$ac_compile"
|
|
fi
|
|
])
|
|
dnl Redefine _AC_CHECK_DECL_BODY so that it references ac_compile_for_check_decl
|
|
dnl instead of ac_compile. If, for whatever reason, the override of AC_PROG_CC
|
|
dnl in zzgnulib.m4 is inactive, use the original ac_compile.
|
|
m4_define([_AC_CHECK_DECL_BODY],
|
|
[ ac_save_ac_compile="$ac_compile"
|
|
if test -n "$ac_compile_for_check_decl"; then
|
|
ac_compile="$ac_compile_for_check_decl"
|
|
fi]
|
|
m4_defn([_AC_CHECK_DECL_BODY])[ ac_compile="$ac_save_ac_compile"
|
|
])
|
|
|
|
# gl_00GNULIB
|
|
# -----------
|
|
# Witness macro that this file has been included. Needed to force
|
|
# Automake to include this file prior to all other gnulib .m4 files.
|
|
AC_DEFUN([gl_00GNULIB])
|