mirror of
git://git.sv.gnu.org/emacs.git
synced 2025-12-26 15:21:51 -08:00
5d89a9c284
This incorporates: 2020-07-30 work around some Oracle Studio attribute bugs 2020-07-29 fsusage, regex, stat-size: remove Cray support 2020-07-26 inttypes: remove support for AIX 4 2020-07-26 gettimeofday: remove workaround for Mac OS X 10.0 2020-07-26 don't require gl_LOCALTIME_BUFFER_DEFAULTS 2020-07-26 alloca: remove Cray-2 and Cray Y-MP support 2020-07-26 libgmp: remove dependency on havelib 2020-07-26 libgmp: remove HAVE_GMP, LIB_GMP 2020-07-25 multiarch: prepare for x86_64+arm64 universal in macOS 11 2020-07-25 sigprocmask: small autoconf macro improvement 2020-07-25 small autoconf macro improvements 2020-07-24 timespec: remove dependence on ‘verify’ 2020-07-24 optimize a few more three-valued comparisons 2020-07-24 fix _GL_CMP parenthesization typo 2020-07-23 optimize three-valued comparison between integers 2020-07-24 doc: update for Mac OS X 10.13 2020-07-23 fchmodat, lchmod: use /proc on Cygwin 2020-07-21 inttypes: fix PRI*PTR and SCN*PTR on 64-bit native Windows 2020-07-12 libgmp: avoid warning when --without-libgmp is used 2020-07-12 libgmp: link to the correct shared library * lib/mini-gmp-gnulib.c: Ignore -Wsuggest-attribute=malloc only for * build-aux/config.guess, build-aux/config.sub: * build-aux/install-sh, doc/misc/texinfo.tex, lib/c-strcasecmp.c: * lib/c-strncasecmp.c, lib/fchmodat.c, lib/fsusage.c: * lib/gettimeofday.c, lib/inttypes.in.h, lib/lchmod.c: * lib/mini-gmp-gnulib.c, lib/nstrftime.c, lib/regex.h, lib/timespec.h: * m4/alloca.m4, m4/getgroups.m4, m4/gettimeofday.m4: * m4/gnulib-common.m4, m4/inttypes.m4, m4/libgmp.m4, m4/mktime.m4: * m4/multiarch.m4: Copy from Gnulib. * lib/gnulib.mk.in, m4/gnulib-comp.m4: Regenerate. * src/Makefile.in, test/Makefile.in (LIBGMP): Rename from LIB_GMP for compatibility with Gnulib. All uses changed.
65 lines
2.1 KiB
Text
65 lines
2.1 KiB
Text
# multiarch.m4 serial 9
|
|
dnl Copyright (C) 2008-2020 Free Software Foundation, Inc.
|
|
dnl This file is free software; the Free Software Foundation
|
|
dnl gives unlimited permission to copy and/or distribute it,
|
|
dnl with or without modifications, as long as this notice is preserved.
|
|
|
|
# Determine whether the compiler is or may be producing universal binaries.
|
|
#
|
|
# On Mac OS X 10.5 and later systems, the user can create libraries and
|
|
# executables that work on multiple system types--known as "fat" or
|
|
# "universal" binaries--by specifying multiple '-arch' options to the
|
|
# compiler but only a single '-arch' option to the preprocessor. Like
|
|
# this:
|
|
#
|
|
# ./configure CC="gcc -arch i386 -arch x86_64 -arch ppc -arch ppc64" \
|
|
# CXX="g++ -arch i386 -arch x86_64 -arch ppc -arch ppc64" \
|
|
# CPP="gcc -E" CXXCPP="g++ -E"
|
|
#
|
|
# Detect this situation and set APPLE_UNIVERSAL_BUILD accordingly.
|
|
|
|
AC_DEFUN_ONCE([gl_MULTIARCH],
|
|
[
|
|
dnl Code similar to autoconf-2.63 AC_C_BIGENDIAN.
|
|
AC_CACHE_CHECK([whether the compiler produces multi-arch binaries],
|
|
[gl_cv_c_multiarch],
|
|
[gl_cv_c_multiarch=no
|
|
AC_COMPILE_IFELSE(
|
|
[AC_LANG_SOURCE(
|
|
[[#ifndef __APPLE_CC__
|
|
not a universal capable compiler
|
|
#endif
|
|
typedef int dummy;
|
|
]])],
|
|
[
|
|
dnl Check for potential -arch flags. It is not universal unless
|
|
dnl there are at least two -arch flags with different values.
|
|
arch=
|
|
prev=
|
|
for word in ${CC} ${CFLAGS} ${CPPFLAGS} ${LDFLAGS}; do
|
|
if test -n "$prev"; then
|
|
case $word in
|
|
i?86 | x86_64 | ppc | ppc64 | arm | arm64)
|
|
if test -z "$arch" || test "$arch" = "$word"; then
|
|
arch="$word"
|
|
else
|
|
gl_cv_c_multiarch=yes
|
|
fi
|
|
;;
|
|
esac
|
|
prev=
|
|
else
|
|
if test "x$word" = "x-arch"; then
|
|
prev=arch
|
|
fi
|
|
fi
|
|
done
|
|
])
|
|
])
|
|
if test $gl_cv_c_multiarch = yes; then
|
|
APPLE_UNIVERSAL_BUILD=1
|
|
else
|
|
APPLE_UNIVERSAL_BUILD=0
|
|
fi
|
|
AC_SUBST([APPLE_UNIVERSAL_BUILD])
|
|
])
|