mirror of
git://git.sv.gnu.org/emacs.git
synced 2025-12-05 22:20:24 -08:00
7e2a154398
This incorporates: 2018-11-03 nstrftime: simplify test for mktime failure 2018-11-02 gnulib-common.m4: port _Noreturn to C++ 2018-10-22 std-gnu11: Support Autoconf versions < 2.64 2018-10-22 Assume Autoconf >= 2.63 2018-10-16 Remove support for Ultrix 2018-10-16 getloadavg: Remove support for ConvexOS 2018-10-16 getloadavg: Remove support for Sony NEWS 2018-10-16 Remove support for Dynix/ptx 2018-10-16 fsusage: Remove support for AIX 3 2018-10-16 fsusage, stat-size, getloadavg: Remove support for AIX PS/2 2018-10-16 getloadavg: Remove support for HP-UX on m68k 2018-10-16 fsusage, mountlist: Remove support for DolphinOS 2018-10-16 getloadavg: Remove support for Alliant FX/2800 2018-10-16 getloadavg: Remove support for tek4300 2018-10-16 getloadavg: Remove support for Ardent * build-aux/config.guess, build-aux/config.sub, lib/_Noreturn.h: * lib/fsusage.c, lib/getgroups.c, lib/getloadavg.c: * lib/nstrftime.c, lib/time.in.h, m4/errno_h.m4: * m4/fsusage.m4, m4/getgroups.m4, m4/gnulib-common.m4, m4/longlong.m4: * m4/std-gnu11.m4, m4/stdint.m4: Copy from Gnulib. * lib/gnulib.mk.in, m4/gnulib-comp.m4: Regenerate:
109 lines
3.7 KiB
Text
109 lines
3.7 KiB
Text
# serial 21
|
|
|
|
dnl From Jim Meyering.
|
|
dnl A wrapper around AC_FUNC_GETGROUPS.
|
|
|
|
# Copyright (C) 1996-1997, 1999-2004, 2008-2018 Free Software Foundation, Inc.
|
|
#
|
|
# This file is free software; the Free Software Foundation
|
|
# gives unlimited permission to copy and/or distribute it,
|
|
# with or without modifications, as long as this notice is preserved.
|
|
|
|
m4_version_prereq([2.70], [] ,[
|
|
|
|
# This is taken from the following Autoconf patch:
|
|
# https://git.savannah.gnu.org/gitweb/?p=autoconf.git;a=commitdiff;h=7fbb553727ed7e0e689a17594b58559ecf3ea6e9
|
|
AC_DEFUN([AC_FUNC_GETGROUPS],
|
|
[
|
|
AC_REQUIRE([AC_TYPE_GETGROUPS])dnl
|
|
AC_REQUIRE([AC_TYPE_SIZE_T])dnl
|
|
AC_REQUIRE([AC_CANONICAL_HOST])dnl for cross-compiles
|
|
AC_CHECK_FUNC([getgroups])
|
|
|
|
# If we don't yet have getgroups, see if it's in -lbsd.
|
|
# This is reported to be necessary on an ITOS 3000WS running SEIUX 3.1.
|
|
ac_save_LIBS=$LIBS
|
|
if test $ac_cv_func_getgroups = no; then
|
|
AC_CHECK_LIB(bsd, getgroups, [GETGROUPS_LIB=-lbsd])
|
|
fi
|
|
|
|
# Run the program to test the functionality of the system-supplied
|
|
# getgroups function only if there is such a function.
|
|
if test $ac_cv_func_getgroups = yes; then
|
|
AC_CACHE_CHECK([for working getgroups], [ac_cv_func_getgroups_works],
|
|
[AC_RUN_IFELSE(
|
|
[AC_LANG_PROGRAM(
|
|
[AC_INCLUDES_DEFAULT],
|
|
[[/* On NeXTstep 3.2, getgroups (0, 0) always fails. */
|
|
return getgroups (0, 0) == -1;]])
|
|
],
|
|
[ac_cv_func_getgroups_works=yes],
|
|
[ac_cv_func_getgroups_works=no],
|
|
[case "$host_os" in # ((
|
|
# Guess yes on glibc systems.
|
|
*-gnu* | gnu*) ac_cv_func_getgroups_works="guessing yes" ;;
|
|
# If we don't know, assume the worst.
|
|
*) ac_cv_func_getgroups_works="guessing no" ;;
|
|
esac
|
|
])
|
|
])
|
|
else
|
|
ac_cv_func_getgroups_works=no
|
|
fi
|
|
case "$ac_cv_func_getgroups_works" in
|
|
*yes)
|
|
AC_DEFINE([HAVE_GETGROUPS], [1],
|
|
[Define to 1 if your system has a working `getgroups' function.])
|
|
;;
|
|
esac
|
|
LIBS=$ac_save_LIBS
|
|
])# AC_FUNC_GETGROUPS
|
|
|
|
])
|
|
|
|
AC_DEFUN([gl_FUNC_GETGROUPS],
|
|
[
|
|
AC_REQUIRE([AC_TYPE_GETGROUPS])
|
|
AC_REQUIRE([gl_UNISTD_H_DEFAULTS])
|
|
AC_REQUIRE([AC_CANONICAL_HOST]) dnl for cross-compiles
|
|
|
|
AC_FUNC_GETGROUPS
|
|
if test $ac_cv_func_getgroups != yes; then
|
|
HAVE_GETGROUPS=0
|
|
else
|
|
if test "$ac_cv_type_getgroups" != gid_t \
|
|
|| { case "$ac_cv_func_getgroups_works" in
|
|
*yes) false;;
|
|
*) true;;
|
|
esac
|
|
}; then
|
|
REPLACE_GETGROUPS=1
|
|
AC_DEFINE([GETGROUPS_ZERO_BUG], [1], [Define this to 1 if
|
|
getgroups(0,NULL) does not return the number of groups.])
|
|
else
|
|
dnl Detect FreeBSD bug; POSIX requires getgroups(-1,ptr) to fail.
|
|
AC_CACHE_CHECK([whether getgroups handles negative values],
|
|
[gl_cv_func_getgroups_works],
|
|
[AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
|
|
[[int size = getgroups (0, 0);
|
|
gid_t *list = malloc (size * sizeof *list);
|
|
int result = getgroups (-1, list) != -1;
|
|
free (list);
|
|
return result;]])],
|
|
[gl_cv_func_getgroups_works=yes],
|
|
[gl_cv_func_getgroups_works=no],
|
|
[case "$host_os" in
|
|
# Guess yes on glibc systems.
|
|
*-gnu* | gnu*) gl_cv_func_getgroups_works="guessing yes" ;;
|
|
# If we don't know, assume the worst.
|
|
*) gl_cv_func_getgroups_works="guessing no" ;;
|
|
esac
|
|
])])
|
|
case "$gl_cv_func_getgroups_works" in
|
|
*yes) ;;
|
|
*) REPLACE_GETGROUPS=1 ;;
|
|
esac
|
|
fi
|
|
fi
|
|
test -n "$GETGROUPS_LIB" && LIBS="$GETGROUPS_LIB $LIBS"
|
|
])
|