mirror of
git://git.sv.gnu.org/emacs.git
synced 2026-01-02 02:10:46 -08:00
b6aa3446df
This incorporates: 2017-04-30 strftime-fixes: New module 2017-04-30 mktime: Work around TZ problem on native Windows 2017-04-30 ctime, localtime: New modules 2017-04-30 gettimeofday: Provide higher resolution on native Windows 2017-04-29 utime-h: Modernize handling of 'struct utimbuf' 2017-04-29 Make use of module 'utime-h' 2017-04-30 Fix a few typos * admin/merge-gnulib (AVOIDED_MODULES): Avoid utime-h, too. * lib/gettimeofday.c, lib/mktime.c, lib/time.in.h, lib/utimens.c: * m4/gettimeofday.m4, m4/include_next.m4, m4/mktime.m4: * m4/strftime.m4, m4/time_h.m4, m4/timegm.m4, m4/utimens.m4: Copy from gnulib. * lib/gnulib.mk.in, m4/gnulib-comp.m4: Regenerate.
49 lines
1.7 KiB
Text
49 lines
1.7 KiB
Text
dnl Copyright (C) 2003-2017 Free Software Foundation, Inc.
|
|
dnl This file is free software; the Free Software Foundation
|
|
dnl gives unlimited permission to copy and/or distribute it,
|
|
dnl with or without modifications, as long as this notice is preserved.
|
|
|
|
dnl serial 8
|
|
|
|
AC_DEFUN([gl_UTIMENS],
|
|
[
|
|
dnl Prerequisites of lib/utimens.c.
|
|
AC_REQUIRE([gl_FUNC_UTIMES])
|
|
AC_REQUIRE([gl_CHECK_TYPE_STRUCT_TIMESPEC])
|
|
AC_REQUIRE([AC_CANONICAL_HOST]) dnl for cross-compiles
|
|
AC_CHECK_FUNCS_ONCE([futimes futimesat futimens utimensat lutimes])
|
|
|
|
if test $ac_cv_func_futimens = no && test $ac_cv_func_futimesat = yes; then
|
|
dnl FreeBSD 8.0-rc2 mishandles futimesat(fd,NULL,time). It is not
|
|
dnl standardized, but Solaris implemented it first and uses it as
|
|
dnl its only means to set fd time.
|
|
AC_CACHE_CHECK([whether futimesat handles NULL file],
|
|
[gl_cv_func_futimesat_works],
|
|
[touch conftest.file
|
|
AC_RUN_IFELSE([AC_LANG_PROGRAM([[
|
|
#include <stddef.h>
|
|
#include <sys/times.h>
|
|
#include <fcntl.h>
|
|
]], [[ int fd = open ("conftest.file", O_RDWR);
|
|
if (fd < 0) return 1;
|
|
if (futimesat (fd, NULL, NULL)) return 2;
|
|
]])],
|
|
[gl_cv_func_futimesat_works=yes],
|
|
[gl_cv_func_futimesat_works=no],
|
|
[case "$host_os" in
|
|
# Guess yes on glibc systems.
|
|
*-gnu*) gl_cv_func_futimesat_works="guessing yes" ;;
|
|
# If we don't know, assume the worst.
|
|
*) gl_cv_func_futimesat_works="guessing no" ;;
|
|
esac
|
|
])
|
|
rm -f conftest.file])
|
|
case "$gl_cv_func_futimesat_works" in
|
|
*yes) ;;
|
|
*)
|
|
AC_DEFINE([FUTIMESAT_NULL_BUG], [1],
|
|
[Define to 1 if futimesat mishandles a NULL file name.])
|
|
;;
|
|
esac
|
|
fi
|
|
])
|