mirror of
git://git.sv.gnu.org/emacs.git
synced 2026-01-04 11:00:45 -08:00
8ca4162ecd
* admin/merge-gnulib (GNULIB_MODULES): * cross/lib/getopt-pfx-core.h (optind): * cross/lib/limits.in.h (BOOL_WIDTH): * cross/lib/math.in.h: * cross/lib/stpncpy.c (__stpncpy): * cross/lib/string.in.h: * lib/getopt-pfx-core.h (optind): * lib/gnulib.mk.in (ANDROID_MIN_SDK): (GL_COND_OBJ_STDIO_READ_CONDITION): (LIBS): (NDK_BUILD_AR): (REPLACE__EXIT): (libgnu_a_SOURCES): * lib/limits.in.h (BOOL_WIDTH): * lib/math.in.h: * lib/stpncpy.c (__stpncpy): * lib/string.in.h: * m4/assert_h.m4 (gl_ASSERT_H): * m4/fdopendir.m4 (gl_FUNC_FDOPENDIR): * m4/getdelim.m4 (gl_FUNC_GETDELIM): * m4/getline.m4 (gl_FUNC_GETLINE): * m4/gnulib-common.m4 (gl_COMMON_BODY): (gl_CONDITIONAL_HEADER): (gl_CHECK_FUNCS_ANDROID): * m4/gnulib-comp.m4 (gl_EARLY): (gl_INIT): (gl_FILE_LIST): * m4/limits-h.m4: * m4/lstat.m4 (gl_FUNC_LSTAT_FOLLOWS_SLASHED_SYMLINK): * m4/malloc.m4 (_AC_FUNC_MALLOC_IF): * m4/printf.m4 (gl_PRINTF_SIZES_C99): (gl_PRINTF_INFINITE): (gl_PRINTF_INFINITE_LONG_DOUBLE): (gl_PRINTF_DIRECTIVE_A): (gl_PRINTF_DIRECTIVE_F): (gl_PRINTF_FLAG_ZERO): (gl_SNPRINTF_PRESENCE): (gl_SNPRINTF_DIRECTIVE_N): (gl_VSNPRINTF_ZEROSIZE_C99): * m4/pselect.m4 (gl_FUNC_PSELECT): * m4/readlink.m4 (gl_FUNC_READLINK): * m4/realloc.m4 (_AC_FUNC_REALLOC_IF): * m4/signbit.m4 (gl_SIGNBIT): * m4/stpncpy.m4 (gl_FUNC_STPNCPY): * m4/symlink.m4 (gl_FUNC_SYMLINK): Add gnulib module stpncpy. * src/android.c: Include string.h.
73 lines
2.6 KiB
Text
73 lines
2.6 KiB
Text
# assert-h.m4
|
|
dnl Copyright (C) 2011-2023 Free Software Foundation, Inc.
|
|
dnl This file is free software; the Free Software Foundation
|
|
dnl gives unlimited permission to copy and/or distribute it,
|
|
dnl with or without modifications, as long as this notice is preserved.
|
|
|
|
dnl From Paul Eggert.
|
|
|
|
AC_DEFUN([gl_ASSERT_H],
|
|
[
|
|
AC_CACHE_CHECK([for static_assert], [gl_cv_static_assert],
|
|
[gl_save_CFLAGS=$CFLAGS
|
|
for gl_working in "yes, a keyword" "yes, an <assert.h> macro"; do
|
|
AS_CASE([$gl_working],
|
|
[*assert.h*], [CFLAGS="$gl_save_CFLAGS -DINCLUDE_ASSERT_H"])
|
|
|
|
AC_COMPILE_IFELSE(
|
|
[AC_LANG_PROGRAM(
|
|
[[#if defined __clang__ && __STDC_VERSION__ < 202311
|
|
#pragma clang diagnostic error "-Wc2x-extensions"
|
|
#pragma clang diagnostic error "-Wc++1z-extensions"
|
|
#endif
|
|
#ifdef INCLUDE_ASSERT_H
|
|
#include <assert.h>
|
|
#endif
|
|
static_assert (2 + 2 == 4, "arithmetic does not work");
|
|
static_assert (2 + 2 == 4);
|
|
]],
|
|
[[
|
|
static_assert (sizeof (char) == 1, "sizeof does not work");
|
|
static_assert (sizeof (char) == 1);
|
|
]])],
|
|
[gl_cv_static_assert=$gl_working],
|
|
[gl_cv_static_assert=no])
|
|
CFLAGS=$gl_save_CFLAGS
|
|
test "$gl_cv_static_assert" != no && break
|
|
done])
|
|
|
|
GL_GENERATE_ASSERT_H=false
|
|
AS_CASE([$gl_cv_static_assert],
|
|
[yes*keyword*],
|
|
[AC_DEFINE([HAVE_C_STATIC_ASSERT], [1],
|
|
[Define to 1 if the static_assert keyword works.])],
|
|
[no],
|
|
[GL_GENERATE_ASSERT_H=true
|
|
gl_NEXT_HEADERS([assert.h])])
|
|
|
|
dnl The "zz" puts this toward config.h's end, to avoid potential
|
|
dnl collisions with other definitions.
|
|
dnl #undef assert so that programs are not tempted to use it without
|
|
dnl specifically including assert.h.
|
|
dnl #undef __ASSERT_H__ so that on IRIX, when programs later include
|
|
dnl <assert.h>, this include actually defines assert.
|
|
dnl Break the #undef_s apart with a comment so that 'configure' does
|
|
dnl not comment them out.
|
|
AH_VERBATIM([zzstatic_assert],
|
|
[#if (!defined HAVE_C_STATIC_ASSERT && !defined assert \
|
|
&& (!defined __cplusplus \
|
|
|| (__cpp_static_assert < 201411 \
|
|
&& __GNUG__ < 6 && __clang_major__ < 6)))
|
|
#include <assert.h>
|
|
#undef/**/assert
|
|
#ifdef __sgi
|
|
#undef/**/__ASSERT_H__
|
|
#endif
|
|
/* Solaris 11.4 <assert.h> defines static_assert as a macro with 2 arguments.
|
|
We need it also to be invocable with a single argument. */
|
|
#if defined __sun && (__STDC_VERSION__ - 0 >= 201112L) && !defined __cplusplus
|
|
#undef/**/static_assert
|
|
#define static_assert _Static_assert
|
|
#endif
|
|
#endif])
|
|
])
|