mirror of
git://git.sv.gnu.org/emacs.git
synced 2026-02-28 19:00:42 -08:00
a3c5530975
This incorporates: 2019-03-23 Support cross-compilation to musl libc 2019-03-23 noreturn: In C++ mode with clang, use _Noreturn as fallback 2019-03-22 _Noreturn: beware of C's _Noreturn in C++ pre C++11 2019-03-19 Help making signal handlers more reliable 2019-03-18 _Noreturn: clang and MSVC do support [[noreturn]] in C++11 2019-03-17 _Noreturn: GCC 4.7 does not support [[noreturn]] in C++11 2019-03-14 all: Update URLs to msdn.microsoft.com * doc/misc/texinfo.tex, lib/_Noreturn.h, lib/gettimeofday.c: * lib/mktime.c, lib/regcomp.c, lib/regexec.c, lib/stat-time.h: * lib/utimens.c, m4/fdopendir.m4, m4/getgroups.m4: * m4/gettimeofday.m4, m4/gnulib-common.m4, m4/putenv.m4, m4/utimes.m4: Update from gnulib.
63 lines
1.8 KiB
Text
63 lines
1.8 KiB
Text
# serial 11
|
|
# See if we need to provide fdopendir.
|
|
|
|
dnl Copyright (C) 2009-2019 Free Software Foundation, Inc.
|
|
dnl This file is free software; the Free Software Foundation
|
|
dnl gives unlimited permission to copy and/or distribute it,
|
|
dnl with or without modifications, as long as this notice is preserved.
|
|
|
|
# Written by Eric Blake.
|
|
|
|
AC_DEFUN([gl_FUNC_FDOPENDIR],
|
|
[
|
|
AC_REQUIRE([gl_DIRENT_H_DEFAULTS])
|
|
AC_REQUIRE([AC_CANONICAL_HOST]) dnl for cross-compiles
|
|
|
|
AC_REQUIRE([gl_USE_SYSTEM_EXTENSIONS])
|
|
|
|
dnl FreeBSD 7.3 has the function, but failed to declare it.
|
|
AC_CHECK_DECLS([fdopendir], [], [HAVE_DECL_FDOPENDIR=0], [[
|
|
#include <dirent.h>
|
|
]])
|
|
AC_CHECK_FUNCS_ONCE([fdopendir])
|
|
if test $ac_cv_func_fdopendir = no; then
|
|
HAVE_FDOPENDIR=0
|
|
else
|
|
AC_CACHE_CHECK([whether fdopendir works],
|
|
[gl_cv_func_fdopendir_works],
|
|
[AC_RUN_IFELSE([AC_LANG_PROGRAM([[
|
|
#include <dirent.h>
|
|
#include <fcntl.h>
|
|
#include <unistd.h>
|
|
#if !HAVE_DECL_FDOPENDIR
|
|
extern
|
|
# ifdef __cplusplus
|
|
"C"
|
|
# endif
|
|
DIR *fdopendir (int);
|
|
#endif
|
|
]], [int result = 0;
|
|
int fd = open ("conftest.c", O_RDONLY);
|
|
if (fd < 0) result |= 1;
|
|
if (fdopendir (fd)) result |= 2;
|
|
if (close (fd)) result |= 4;
|
|
return result;])],
|
|
[gl_cv_func_fdopendir_works=yes],
|
|
[gl_cv_func_fdopendir_works=no],
|
|
[case "$host_os" in
|
|
# Guess yes on glibc systems.
|
|
*-gnu*) gl_cv_func_fdopendir_works="guessing yes" ;;
|
|
# Guess yes on musl systems.
|
|
*-musl*) gl_cv_func_fdopendir_works="guessing yes" ;;
|
|
# If we don't know, assume the worst.
|
|
*) gl_cv_func_fdopendir_works="guessing no" ;;
|
|
esac
|
|
])])
|
|
case "$gl_cv_func_fdopendir_works" in
|
|
*yes) ;;
|
|
*)
|
|
REPLACE_FDOPENDIR=1
|
|
;;
|
|
esac
|
|
fi
|
|
])
|